Here's a generic technique to render a resultset using dynamic html. There
may be better ways to accomplish the task, though.
<html>
<head>
<body>
<Script Language="VBScript">
Sub btnListBackups_OnClick()
Set oConnection = CreateObject("ADODB.Connection")
oConnection.Open "Provider=SQLOLEDB" & _
";Data Source=" & "DBDELTA1" & _
";Integrated Security=SSPI"
Set recordSet = oConnection.Execute("EXEC tempdb..sp_lastback")
myResultTable = "<table border=""1"">"
myResultTable = myResultTable & "<tr>"
For i = 0 To recordSet.Fields.Count - 1
myResultTable = myResultTable & _
"<th>" & _
recordSet.Fields(i).Name & _
"</th>"
Next
myResultTable = myResultTable & "</tr>"
Do While Not recordSet.EOF
myResultTable = myResultTable & "<tr>"
For i = 0 To recordSet.Fields.Count - 1
myResultTable = myResultTable & _
"<td>" & _
recordSet.Fields(i).Value & _
"</td>"
Next
myResultTable = myResultTable & "</tr>"
recordSet.MoveNext
Loop
myResultTable = myResultTable & "</table>"
recordSet.Close
oConnection.Close
Results.innerHTML = myResultTable
End Sub
</script>
<input type="button" id="btnListBackups" value="List Backups">
<hr>
<nobr Id=Results></nobr>
</body>
</html>
--
Hope this helps.
Dan Guzman
SQL Server MVP
[quoted text, click to view] "sumGirl" <emebohw@netscape.net> wrote in message
news:a5e13cff.0410141529.23a19fd8@posting.google.com...
> Hi all. I have a stored procedure on my sql server that returns a
> simple informtation about that tim a database was backed up. I owuld
> like to create an HTA that operator types can look at to make sure
> that the backups finished, can someone help me do this?
>
> The stored procedure in called sp_lastback and the output looks like
> this:
>
> database days since backup timestamp of backup
> dbase1 0 2004-10-14 00:41:21.000
> dbase2 0 2004-10-14 00:08:36.000
> dbase3 1 2004-10-13 22:46:57.000
>
> Can this be done? If someone could help me with this simple problem, I
> could probably reuse the same method a 100 useful ways.
>
> Thanks in advance!
